Theory Weak_Cong_Sim_Pres

(* 
   Title: The Calculus of Communicating Systems   
   Author/Maintainer: Jesper Bengtson (jebe@itu.dk), 2012
*)
theory Weak_Cong_Sim_Pres
  imports Weak_Cong_Sim
begin

lemma actPres:
  fixes P    :: ccs
  and   Q    :: ccs
  and   Rel  :: "(ccs × ccs) set"
  and   a    :: name
  and   Rel' :: "(ccs × ccs) set"

  assumes "(P, Q) ∈ Rel"

  shows "α.(P) ↝<Rel> α.(Q)"
using assms
by(fastforce simp add: weakCongSimulation_def elim: actCases intro: weakCongAction)

lemma sumPres:
  fixes P   :: ccs
  and   Q   :: ccs
  and   Rel :: "(ccs × ccs) set"

  assumes "P ↝<Rel> Q"
  and     "Rel ⊆ Rel'"
  and     "Id ⊆ Rel'"

  shows "P ⊕ R ↝<Rel'> Q ⊕ R"
using assms
by(force simp add: weakCongSimulation_def elim: sumCases intro: weakCongSum1 weakCongSum2 transitionWeakCongTransition)

lemma parPres:
  fixes P   :: ccs
  and   Q   :: ccs
  and   Rel :: "(ccs × ccs) set"

  assumes "P ↝<Rel> Q"
  and     "(P, Q) ∈ Rel"
  and     C1: "⋀S T U. (S, T) ∈ Rel ⟹ (S ∥ U, T ∥ U) ∈ Rel'"

  shows "P ∥ R ↝<Rel'> Q ∥ R"
proof(induct rule: weakSimI)
  case(Sim α QR)
  from ‹Q ∥ R ⟼α ≺ QR›
  show ?case
  proof(induct rule: parCases)
    case(cPar1 Q')
    from ‹P ↝<Rel> Q› ‹Q ⟼α ≺ Q'› obtain P' where "P ⟹α ≺ P'" and "(P', Q') ∈ Rel" 
      by(rule weakSimE)
    from ‹P ⟹α ≺ P'› have "P ∥ R ⟹α ≺ P' ∥ R" by(rule weakCongPar1)
    moreover from ‹(P', Q') ∈ Rel› have "(P' ∥ R, Q' ∥ R) ∈ Rel'" by(rule C1)
    ultimately show ?case by blast
  next
    case(cPar2 R')
    from ‹R ⟼α ≺ R'› have "R ⟹α ≺ R'" by(rule transitionWeakCongTransition)
    hence "P ∥ R ⟹α ≺ P ∥ R'" by(rule weakCongPar2)
    moreover from ‹(P, Q) ∈ Rel› have "(P ∥ R', Q ∥ R') ∈ Rel'" by(rule C1)
    ultimately show ?case by blast
  next
    case(cComm Q' R' α)
    from ‹P ↝<Rel> Q› ‹Q ⟼α ≺ Q'› obtain P' where "P ⟹α ≺ P'" and "(P', Q') ∈ Rel" 
      by(rule weakSimE)
    from ‹R ⟼(coAction α) ≺ R'› have "R ⟹(coAction α) ≺ R'"
      by(rule transitionWeakCongTransition)
    with ‹P ⟹α ≺ P'› have "P ∥ R ⟹τ ≺ P' ∥ R'" using ‹α ≠ τ› 
      by(rule weakCongSync)
    moreover from ‹(P', Q') ∈ Rel› have "(P' ∥ R', Q' ∥ R') ∈ Rel'" by(rule C1)
    ultimately show ?case by blast
  qed
qed

lemma resPres:
  fixes P   :: ccs
  and   Rel :: "(ccs × ccs) set"
  and   Q   :: ccs
  and   x   :: name

  assumes "P ↝<Rel> Q"
  and     "⋀R S y. (R, S) ∈ Rel ⟹ (⦇νy⦈R, ⦇νy⦈S) ∈ Rel'"

  shows "⦇νx⦈P ↝<Rel'> ⦇νx⦈Q"
using assms
by(fastforce simp add: weakCongSimulation_def elim: resCases intro: weakCongRes)

lemma bangPres:
  fixes P    :: ccs
  and   Q    :: ccs
  and   Rel  :: "(ccs × ccs) set"
  and   Rel' :: "(ccs × ccs) set"

  assumes "(P, Q) ∈ Rel"
  and     C1: "⋀R S. (R, S) ∈ Rel ⟹ R ↝<Rel'> S"
  and     C2: "Rel ⊆ Rel'"

  shows "!P ↝<bangRel Rel'> !Q"
proof(induct rule: weakSimI)
  case(Sim α Q')
  {
    fix Pa α Q'
    assume "!Q ⟼α ≺ Q'" and "(Pa, !Q) ∈ bangRel Rel"
    hence "∃P'. Pa ⟹α ≺ P' ∧ (P', Q') ∈ bangRel Rel'"
    proof(nominal_induct arbitrary: Pa rule: bangInduct)
      case(cPar1 α Q')
      from ‹(Pa, Q ∥ !Q) ∈ bangRel Rel› 
      show ?case
      proof(induct rule: BRParCases)
        case(BRPar P R)
        from ‹(P, Q) ∈ Rel› have "P ↝<Rel'> Q" by(rule C1)
        with ‹Q ⟼α ≺ Q'› obtain P' where "P ⟹α ≺ P'" and "(P', Q') ∈ Rel'"
          by(blast dest: weakSimE)
        from ‹P ⟹α ≺ P'› have "P ∥ R ⟹α ≺ P' ∥ R" by(rule weakCongPar1)
        moreover from ‹(R, !Q) ∈ bangRel Rel› C2 have "(R, !Q) ∈ bangRel Rel'"
          by induct (auto intro: bangRel.BRPar bangRel.BRBang)
        with ‹(P', Q') ∈ Rel'› have "(P' ∥ R, Q' ∥ !Q) ∈ bangRel Rel'"
          by(rule bangRel.BRPar)
        ultimately show ?case by blast
      qed
    next
      case(cPar2 α Q')
      from ‹(Pa, Q ∥ !Q) ∈ bangRel Rel›
      show ?case
      proof(induct rule: BRParCases)
        case(BRPar P R)
        from ‹(R, !Q) ∈ bangRel Rel› obtain R' where "R ⟹α ≺ R'" and "(R', Q') ∈ bangRel Rel'" using cPar2
          by blast
        from ‹R ⟹α ≺ R'› have "P ∥ R ⟹α ≺ P ∥ R'" by(rule weakCongPar2)
        moreover from ‹(P, Q) ∈ Rel› ‹(R', Q') ∈ bangRel Rel'› C2 have "(P ∥ R', Q ∥ Q') ∈ bangRel Rel'" 
          by(blast intro: bangRel.BRPar)
        ultimately show ?case by blast
      qed
    next
      case(cComm a Q' Q'' Pa)
      from ‹(Pa, Q ∥ !Q) ∈ bangRel Rel›
      show ?case
      proof(induct rule: BRParCases)
        case(BRPar P R)
        from ‹(P, Q) ∈ Rel› have "P ↝<Rel'> Q" by(rule C1)
        with ‹Q ⟼a ≺ Q'› obtain P' where "P ⟹a ≺ P'" and "(P', Q') ∈ Rel'"
          by(blast dest: weakSimE)
        from ‹(R, !Q) ∈ bangRel Rel› obtain R' where "R ⟹(coAction a) ≺ R'" and "(R', Q'') ∈ bangRel Rel'" using cComm
          by blast
        from ‹P ⟹a ≺ P'› ‹R ⟹(coAction a) ≺ R'› ‹a ≠ τ› have "P ∥ R ⟹τ ≺ P' ∥ R'" by(rule weakCongSync)
        moreover from ‹(P', Q') ∈ Rel'› ‹(R', Q'') ∈ bangRel Rel'› have "(P' ∥ R', Q' ∥ Q'') ∈ bangRel Rel'"
          by(rule bangRel.BRPar)
        ultimately show ?case by blast
      qed
    next
      case(cBang α Q' Pa)
      from ‹(Pa, !Q) ∈ bangRel Rel›
      show ?case
      proof(induct rule: BRBangCases)
        case(BRBang P)
        from ‹(P, Q) ∈ Rel› have "(!P, !Q) ∈ bangRel Rel" by(rule bangRel.BRBang)
        with ‹(P, Q) ∈ Rel› have "(P ∥ !P, Q ∥ !Q) ∈ bangRel Rel" by(rule bangRel.BRPar)
        then obtain P' where "P ∥ !P ⟹α ≺ P'" and "(P', Q') ∈ bangRel Rel'" using cBang
          by blast
        from ‹P ∥ !P ⟹α ≺ P'› have "!P ⟹α ≺ P'" by(rule weakCongRepl)
        thus ?case using ‹(P', Q') ∈ bangRel Rel'› by blast
      qed
    qed
  }

  moreover from ‹(P, Q) ∈ Rel› have "(!P, !Q) ∈ bangRel Rel" by(rule BRBang) 
  ultimately show ?case using ‹!Q ⟼ α ≺ Q'› by blast
qed

end